&ACCESS RVP
&COMMENT USER specified PLC program
DEF  PLC ( )
   DECL STATE_T STAT
   DECL MODUS_T MODE
   DECL E6POS ACT_Point
   
   LOOP
      ON_ERROR_PROCEED
      IF $ERR.NUMBER > 0 THEN
         Q_ActPosErr = TRUE            
         ERR_CLEAR($ERR)
      ELSE
         Q_ActPosErr=FALSE                         
         IF ($ACT_TOOL==1) AND ($ACT_BASE==1) THEN 
            ON_ERROR_PROCEED
            ACT_Point = $POS_ACT  
            IF ACT_Point.Z>350.0 THEN
               Q_PlaceSafe=TRUE
            ELSE
               Q_PlaceSafe=FALSE 
            ENDIF 
         ELSE
            Q_PlaceSafe=FALSE 
         ENDIF                   
      ENDIF 
      
      IF $FLAG[10] THEN
         CWRITE($CMD,STAT,MODE,"RESET/R1/cell()")
         ;CWRITE($CMD,STAT,MODE,"RESET/R1/MainModule()")
         $FLAG[10]=FALSE
      ENDIF
      IF $FLAG[11] THEN
         CWRITE($CMD,STAT,MODE,"STOP 1")
         $FLAG[11]=FALSE
      ENDIF
      IF $FLAG[12] THEN
         CWRITE($CMD,STAT,MODE,"CANCEL  1")
         $FLAG[12]=FALSE
      ENDIF
      IF $CONF_MESS AND NOT ConfMessSave THEN
         Q_Error1=FALSE
         Q_Error2=FALSE
         Q_Error3=FALSE
         Q_Error4=FALSE
         Q_Error5=FALSE
         Q_Error6=FALSE
         Q_Error7=FALSE
         Q_Error8=FALSE
         Q_Error9=FALSE
         Q_Error10=FALSE
         Q_Error11=FALSE
         Q_Error12=FALSE
         Q_Error13=FALSE
         Q_Error14=FALSE
         Q_Error15=FALSE
         Q_Error16=FALSE
      ENDIF
      ConfMessSave=$CONF_MESS
      
   ENDLOOP
END